select
DropStmt = 'ALTER TABLE [' + ForeignKeys.ForeignTableSchema + 
      '].[' + ForeignKeys.ForeignTableName + 
      '] DROP CONSTRAINT [' + ForeignKeys.ForeignKeyName + ']; ',  
CreateStmt = 'ALTER TABLE [' + ForeignKeys.ForeignTableSchema + 
      '].[' + ForeignKeys.ForeignTableName + 
      '] WITH CHECK ADD CONSTRAINT [' +  ForeignKeys.ForeignKeyName + 
      '] FOREIGN KEY([' + ForeignKeys.ForeignTableColumn + 
      ']) REFERENCES [' + schema_name(sys.objects.schema_id) + '].[' +
  sys.objects.[name] + ']([' +
  sys.columns.[name] + ']) ON DELETE CASCADE; '
 from sys.objects
  inner join sys.columns
    on (sys.columns.[object_id] = sys.objects.[object_id])
  inner join (
    select sys.foreign_keys.[name] as ForeignKeyName
     ,schema_name(sys.objects.schema_id) as ForeignTableSchema
     ,sys.objects.[name] as ForeignTableName
     ,sys.columns.[name]  as ForeignTableColumn
     ,sys.foreign_keys.referenced_object_id as referenced_object_id
     ,sys.foreign_key_columns.referenced_column_id as referenced_column_id
     from sys.foreign_keys
      inner join sys.foreign_key_columns
        on (sys.foreign_key_columns.constraint_object_id
          = sys.foreign_keys.[object_id])
      inner join sys.objects
        on (sys.objects.[object_id]
          = sys.foreign_keys.parent_object_id)
        inner join sys.columns
          on (sys.columns.[object_id]
            = sys.objects.[object_id])
           and (sys.columns.column_id
            = sys.foreign_key_columns.parent_column_id)
    ) ForeignKeys
    on (ForeignKeys.referenced_object_id = sys.objects.[object_id])
     and (ForeignKeys.referenced_column_id = sys.columns.column_id)
 where (sys.objects.[type] = 'U')
  and (sys.objects.[name] not in ('sysdiagrams'))

EXEC sp_MSForEachTable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL' GO

EXEC sp_MSForEachTable 'DELETE FROM ?' GO

EXEC sp_MSForEachTable 'ALTER TABLE ? CHECK CONSTRAINT ALL' GO
					

SELECT
    K_Table = FK.TABLE_NAME,
    FK_Column = CU.COLUMN_NAME,
    PK_Table = PK.TABLE_NAME,
    PK_Column = PT.COLUMN_NAME,
    Constraint_Name = C.CONSTRAINT_NAME
FROM
    INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS C
INNER JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS FK
    ON C.CONSTRAINT_NAME = FK.CONSTRAINT_NAME
INNER JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS PK
    ON C.UNIQUE_CONSTRAINT_NAME = PK.CONSTRAINT_NAME
INNER JOIN INFORMATION_SCHEMA.KEY_COLUMN_USAGE CU
    ON C.CONSTRAINT_NAME = CU.CONSTRAINT_NAME
INNER JOIN (
            SELECT
                i1.TABLE_NAME,
                i2.COLUMN_NAME
            FROM
                INFORMATION_SCHEMA.TABLE_CONSTRAINTS i1
            INNER JOIN INFORMATION_SCHEMA.KEY_COLUMN_USAGE i2
                ON i1.CONSTRAINT_NAME = i2.CONSTRAINT_NAME
            WHERE
                i1.CONSTRAINT_TYPE = 'PRIMARY KEY'
           ) PT
    ON PT.TABLE_NAME = PK.TABLE_NAME

ORDER BY PK_Table

Fuente: Stackoverflow

MS Access y SQL Server tratan de diferente manera a los booleanos, en MS Access -1 es True y 0 es False. En cambio en la base de datos SQL Server se usa el tipo BIT (1 para True y 0 para False).

Luego de realizar la exportación de tablas MS Access a SQL Server es probable que si quieras seguir trabajando con Access como Front tengas muchos problemas con los booleanos.

Una solución es cambiar todos los tipos BIT a Smallint, para así pasar los valores 1 a -1. También hay que realizar los cambios en los valores por default.

A continuación les muestro el Stored Procedure que hice para cambiar todos los tipos BIT a Smallint de todas las tablas.

USE [BaseDeDatosSQL]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE PROCEDURE [dbo].[MAIN_CONVERTIR_BOOLEAN_A_SMALLINT]
AS
BEGIN
	SET NOCOUNT ON;
	DECLARE @nombre_constraint AS NVARCHAR(4000)
	DECLARE @SQL AS NVARCHAR(4000)
	DECLARE @nombre_tabla AS NVARCHAR(255)
	DECLARE @nombre_columna AS NVARCHAR(255)
	DECLARE @nuevo_valor_default AS INTEGER

	DECLARE CUR CURSOR FAST_FORWARD FOR
		SELECT c.table_name, 
			   c.column_name, 
			   CASE 
					WHEN c.column_default = '((1))' THEN -1 ELSE 0
				END AS nuevo_valor_default
		  FROM INFORMATION_SCHEMA.COLUMNS c 
		 WHERE c.data_type = 'bit'
		   AND c.table_catalog = 'BaseDeDatosSQL'
		   AND c.table_schema = 'dbo'
		-- AND c.table_name = 'nombre_tabla'

	OPEN CUR
	FETCH NEXT FROM CUR INTO @nombre_tabla, 
					@nombre_columna, @nuevo_valor_default
	WHILE @@FETCH_STATUS = 0
	BEGIN

		SET @nombre_constraint =
				(
					SELECT name 
					FROM sysobjects so JOIN sysconstraints sc
					ON so.id = sc.constid 
					WHERE object_name(so.parent_obj) 
									= @nombre_tabla 
					AND so.xtype = 'D'
					AND sc.colid = 
					 (SELECT colid FROM syscolumns 
							WHERE id = 
								object_id(@nombre_tabla)
								AND name = @nombre_columna)					
				)

		PRINT '--- TABLA: '  + @nombre_tabla + ' COLUMNA: ' 
			+ @nombre_columna + ' DEFAULT: ' 
			+ RTRIM(CONVERT(CHAR, @nuevo_valor_default)) 
			+ ' ----'

		SELECT @SQL = 'ALTER TABLE [' + @nombre_tabla 
				+ '] ADD [Campo Temporal] SMALLINT;'		
		EXEC sp_executesql @SQL	

		SELECT @SQL = 'UPDATE [' 
				+ @nombre_tabla + '] SET [Campo Temporal] = [' 
				+ @nombre_columna + '];'		
		EXEC sp_executesql @SQL		

		SELECT @SQL = 'ALTER TABLE [' 
				+ @nombre_tabla + '] DROP CONSTRAINT [' 
				+ @nombre_constraint + ']'
		EXEC sp_executesql @SQL	

		SELECT @SQL = 'ALTER TABLE [' 
				+ @nombre_tabla + '] DROP COLUMN [' 
				+ @nombre_columna + '];'		
		EXEC sp_executesql @SQL	

		SELECT @SQL = 'ALTER TABLE [' 
				+ @nombre_tabla + '] ADD [' 
				+ @nombre_columna + '] SMALLINT DEFAULT (' 
				+ RTRIM(CONVERT(CHAR, @nuevo_valor_default)) + ');'		
		EXEC sp_executesql @SQL										

		SELECT @SQL = 'UPDATE [' 
				+ @nombre_tabla + '] SET [' 
				+ @nombre_columna + '] = [Campo Temporal];'		
		EXEC sp_executesql @SQL		

		SELECT @SQL = 'ALTER TABLE [' 
				+ @nombre_tabla + '] DROP COLUMN [Campo Temporal];'		
		EXEC sp_executesql @SQL	

		SELECT @SQL = 'UPDATE [' 
				+ @nombre_tabla + '] SET [' 
				+ @nombre_columna + '] = [' 
				+ @nombre_columna + '] * -1;'		
		EXEC sp_executesql @SQL				

		PRINT '------------ Los cambios se realizaron con éxito --------------'

		FETCH NEXT FROM CUR INTO @nombre_tabla, @nombre_columna, 
							@nuevo_valor_default
	END
	CLOSE CUR;
	DEALLOCATE CUR;
END

• Abrir la base de datos MS Access
• Luego ir a la sección Herramientas de Bases de Datos y hacer click en SQL Server
  
• Luego seleccionar “Crear nueva Base de Datos”
• Especificar el servidor, en este caso es .\SQLEXPRESS (Si usas EXPRESS no aparecerá el server en la lista, tenes que ponerlo a mano).
• Seleccionar “Usar Conexión de Confianza” y mas abajo especifica el nombre de la base de datos que se creara en SQL Server y presionar el botón Siguiente.
• En este punto seleccionamos las tablas que queremos exportar y presionar botón Siguiente.
• Ahora seleccionamos los atributos de las tablas que deseamos exportar y presionamos Sigueinte.
  
• El último paso nos consulta sobre que cambios queremos realizar a la aplicación Access. En mi caso selecciono Ninguno.
• Y por ultimo presionamos “Finalizar” para dar inicio al proceso.